改：マイク＆スピーカセット

micSpeaker links


マイクをクリックしたときに、ダイアログでサウンドが選べるといいね、という
意見をもらったのでマッハで作ってみました。


まず、マイクをタッチします。


サウンド一覧のダイアログがでるので、鳴らしたいサウンドを選択します。
ダイアログはIgnoreを押すまで何度も出てきます。
(今まで通り、チャットでサウンドキーを指定しての操作も可能です。)

ちなみに、サウンドの数が多く、１つのダイアログに入りきらない際の処理は書いてません。
next、prevを出して制御する処理、めんどくさいので…。

そういうのは、モジュールが必要だなあ、モジュールが。
確かlslのイベントで階層化ダイアログモジュールを発表されてた方がいたはず…。

マイク側のソース

integer debug = FALSE;

Trace(string s){

    //debug = TRUE;

    if(debug) llOwnerSay(s);

}

integer ch = 86492;

Init(){

    ResetChannel();

    InitSoundList();

}

ResetChannel(){

    Trace("ResetChannel");

    string desc = llGetObjectDesc();

    if(desc!=""){

        ch = (integer)desc;

    }

    llListen(ch,"",llGetOwner(),"");

    Trace("channel : "+(string)ch);

}

list soundList;

InitSoundList(){

    Trace("InitSoundList");

    soundList = [];

    integer len = llGetInventoryNumber(INVENTORY_SOUND);

    integer i;

    for(i=0;i<len;i++){

        soundList += [llGetInventoryName(INVENTORY_SOUND,i)];

    }

}

ShowDialog(){

    Trace("ShowDialog");

    llDialog(llGetOwner(),"select sound",soundList,ch);

}

string LISTEN_COMMAND = "speak";

string BROADCAST_COMMAND = "harayoki.speakreq";

Speak(string soundName,string vol){

    Trace("Speak "+soundName+" "+vol);

    string soundKeyString = "";

    if(llSubStringIndex(soundName,"#")==0){

        //soundName is index number

        integer i = (integer)llGetSubString(soundName,1,-1);

        soundName = llList2String(soundList,i);

    }

    soundKeyString = (string)llGetInventoryKey(soundName);

    if(soundKeyString==(string)NULL_KEY){

        //soundName is key string

        soundKeyString = soundName;

    }

    string s = BROADCAST_COMMAND+" "+soundKeyString+" "+vol;

    Trace("Speak -> "+s);

    llRegionSay(ch,s);

}

default{

    state_entry(){

        Init();

    }

    touch_start(integer total_number){

        if(llDetectedKey(0)==llGetOwner()){

            ResetChannel();

            ShowDialog();

        }

    }

    listen(integer cha,string name,key id,string mes){

        integer index;

        index = llListFindList(soundList,[mes]);

        if(index!=-1){

            Speak(mes,"1.0");

            ShowDialog();

        }else{

            index = llSubStringIndex(mes,LISTEN_COMMAND+" ");

            if(index==0){

                list l = llParseString2List(mes,[" "],[]);

                Speak(llList2String(l,1),llList2String(l,2));

            }

        }

    }

    changed(integer cha){

        if(cha & CHANGED_INVENTORY){

            InitSoundList();

        }

    }

}

// /86492 speak #0

スタンドの形も若干修正しました。